Inhalter
Gëschter am Marathon 30 Excel Funktiounen an 30 Deeg mir fonnt Text Saiten mat der Funktioun SICH (SEARCH) an och benotzt IFERROR (IFERROR) an ISNUMMER (ISNUMBER) an Situatiounen wou d'Funktioun e Feeler werft.
Den 19. Dag vun eisem Marathon wäerte mir d'Funktioun studéieren MATCH (SEARCH). Et kuckt e Wäert an enger Array op a, wann e Wäert fonnt gëtt, gëtt seng Positioun zréck.
Also, loosst eis op d'Referenzinformatioun iwwer d'Funktioun wenden MATCH (MATCH) a kuckt e puer Beispiller. Wann Dir Är eege Beispiller oder Approche fir mat dëser Funktioun ze schaffen, deelt se w.e.g. an de Kommentaren.
Funktioun 19: MATCH
Funktioun MATCH (MATCH) gëtt d'Positioun vun engem Wäert an enger Array zréck, oder e Feeler #AT (#N/A) wann net fonnt. Eng Array kann entweder zortéiert oder net sortéiert ginn. Funktioun MATCH (MATCH) ass net Fall sensibel.
Wéi kënnt Dir d'MATCH Funktioun benotzen?
Funktioun MATCH (MATCH) gëtt d'Positioun vun engem Element an enger Array zréck, an dëst Resultat kann vun anere Funktiounen benotzt ginn, wéi z. INDEX (INDEX) oder VLOOKUP (VPR). Zum Beispill:
- Fannt d'Positioun vun engem Element an enger onsortéierter Lëscht.
- Benotzt mat WÄART (SELECT) fir d'Studenteleeschtungen op Bréifgraden ze konvertéieren.
- Benotzt mat VLOOKUP (VLOOKUP) fir flexibel Kolonn Auswiel.
- Benotzt mat INDEX (INDEX) fir de nooste Wäert ze fannen.
Syntax MATCH
Funktioun MATCH (MATCH) huet déi folgend Syntax:
MATCH(lookup_value,lookup_array,[match_type])
ПОИСКПОЗ(искомое_значение;просматриваемый_массив;[тип_сопоставления])
- lookup_value (lookup_value) - Kann Text, Zuel oder Boolesch sinn.
- lookup_array (lookup_array) - eng Array oder Array Referenz (nächst Zellen an der selwechter Kolonn oder der selwechter Zeil).
- match_type (match_type) kann dräi Wäerter huelen: -1, 0 or 1. Wann d'Argument ausgelooss gëtt, ass et gläichwäerteg mat 1.
Traps MATCH (MATCH)
Funktioun MATCH (MATCH) gëtt d'Positioun vum fonnt Element zréck, awer net säi Wäert. Wann Dir e Wäert zréck wëllt, benotzt MATCH (MATCH) zesumme mat der Funktioun INDEX (INDEX).
Beispill 1: En Element an enger onsortéierter Lëscht fannen
Fir eng onsortéiert Lëscht, kënnt Dir benotzen 0 als Argument Wäert match_type (match_type) fir no engem genaue Match ze sichen. Wann Dir e genee Match vun enger Textstring wëllt fannen, kënnt Dir Wildcard Zeechen an der Sichwäert benotzen.
Am folgende Beispill, fir d'Positioun vun engem Mount an enger Lëscht ze fannen, kënne mir den Numm vum Mount schreiwen, entweder ganz oder deelweis, mat Wildcards.
=MATCH(D2,B3:B7,0)
=ПОИСКПОЗ(D2;B3:B7;0)
Als Argument lookup_array (lookup_array) Dir kënnt eng Array vu Konstanten benotzen. Am folgende Beispill gëtt de gewënschten Mount an der Zelle D5 aginn, an d'Nimm vun de Méint ginn als zweet Argument fir d'Funktioun ersat. MATCH (MATCH) als Array vu Konstanten. Wann Dir e méi spéit Mount an Zell D5 gitt, zum Beispill, okt (Oktober), da gëtt d'Resultat vun der Funktioun #AT (#N/A).
=MATCH(D5,{"Jan","Feb","Mar"},0)
=ПОИСКПОЗ(D5;{"Jan";"Feb";"Mar"};0)
Beispill 2: Ännere Studentegrade vu Prozentsaz op Buschtawen
Dir kënnt Studentegraden an e Bréifsystem konvertéieren mat der Funktioun MATCH (MATCH) grad wéi Dir hutt mat VLOOKUP (VPR). An dësem Beispill gëtt d'Funktioun a Verbindung mat WÄART (CHOICE), déi d'Devis zréckginn déi mir brauchen. Argument match_type (match_type) ass gläich gesat -1, well d'Scores an der Tabell sinn an ofstigend Uerdnung zortéiert.
Wann d'Argument match_type (Match_Typ) ass -1, d'Resultat ass dee klengste Wäert dee méi grouss ass wéi oder gläichwäerteg zum gewënschten Wäert. An eisem Beispill ass de gewënschte Wäert 54. Well et kee sou Wäert an der Lëscht vun de Partituren ass, gëtt d'Element entsprécht dem Wäert 60 zréck. Zënter 60 ass op der véierter Plaz an der Lëscht, d'Resultat vun der Funktioun WÄART (SELECT) wäert de Wäert sinn deen op der 4. Positioun ass, dh Zell C6, déi de Score D enthält.
=CHOOSE(MATCH(B9,B3:B7,-1),C3,C4,C5,C6,C7)
=ВЫБОР(ПОИСКПОЗ(B9;B3:B7;-1);C3;C4;C5;C6;C7)
Beispill 3: Erstellt eng flexibel Kolonnauswiel fir VLOOKUP (VLOOKUP)
Fir d'Funktioun méi Flexibilitéit ze ginn VLOOKUP (VLOOKUP) Dir kënnt benotzen MATCH (MATCH) fir d'Kolonnnummer ze fannen, anstatt säi Wäert an d'Funktioun ze hardcodéieren. Am folgende Beispill kënnen d'Benotzer eng Regioun an der Zell H1 auswielen, dëst ass de Wäert deen se sichen VLOOKUP (VPR). Als nächst kënne se e Mount an der Zell H2 auswielen, an d'Funktioun MATCH (MATCH) wäert d'Kolonnnummer zréckginn, déi dem Mount entsprécht.
=VLOOKUP(H1,$B$2:$E$5,MATCH(H2,B1:E1,0),FALSE)
=ВПР(H1;$B$2:$E$5;ПОИСКПОЗ(H2;B1:E1;0);ЛОЖЬ)
Beispill 4: Fannt de nooste Wäert mat INDEX (INDEX)
Funktioun MATCH (MATCH) funktionnéiert super a Kombinatioun mat der Funktioun INDEX (INDEX), dee mir e bësse méi no an dësem Marathon wäerte kucken. An dësem Beispill ass d'Funktioun MATCH (MATCH) gëtt benotzt fir déi nooste bei der korrekter Zuel aus verschiddene geschätzten Zuelen ze fannen.
- Funktioun ABS gëtt de Modul vum Ënnerscheed tëscht all geschätzten a korrekten Zuel zréck.
- Funktioun MIN (MIN) fënnt de klengsten Ënnerscheed.
- Funktioun MATCH (MATCH) fënnt d'Adress vum klengsten Ënnerscheed an der Lëscht vun den Ënnerscheeder. Wann et e puer passende Wäerter an der Lëscht sinn, gëtt deen éischten zréckginn.
- Funktioun INDEX (INDEX) gëtt den Numm entspriechend dëser Positioun aus der Lëscht vun Nimm zréck.
=INDEX(B2:B5,MATCH(MIN(ABS(C2:C5-F1)),ABS(C2:C5-F1),0))
=ИНДЕКС(B2:B5;ПОИСКПОЗ(МИН(ABS(C2:C5-F1));ABS(C2:C5-F1);0))
